Imports System.Net
Imports System.net.Sockets
Imports System.IO
Imports System.Windows.Forms
Public Class Form1

    Private ClientSocket As Socket
    Private recvBuffer(8191) As Byte

    Private Sub btnConnect_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnConnect.Click
        If btnConnect.Text = "Disconnect" Then
            Try
                SyncLock ClientSocket
                    ClientSocket.Shutdown(SocketShutdown.Both)
                    ClientSocket.Close()
                End SyncLock
                DisconnectedUI()
            Catch
            End Try
        Else
            ClientSocket = New Socket(AddressFamily.InterNetwork, _
                 SocketType.Stream, ProtocolType.Tcp)
            Dim address As IPAddress = _
                System.Net.Dns.GetHostEntry(txtAddress.Text).AddressList(0)
            Dim endpoint As New IPEndPoint(address, CInt(txtPort.Text))
            ClientSocket.BeginConnect(endpoint, AddressOf Connected, Nothing)
        End If
    End Sub

    Public Sub Connected(ByVal ar As IAsyncResult)
        Try
            ClientSocket.EndConnect(ar)
            '-- Call ConnectedUI
            Dim cb As New SimpleCallback(AddressOf ConnectedUI)
            Me.Invoke(cb)
            '-- Start Receiving Data
            ClientSocket.BeginReceive(recvBuffer, 0, recvBuffer.Length, _
                SocketFlags.None, AddressOf ReceivedData, Nothing)
        Catch ex As Exception
            '-- Call DisconnectedUI
            CallDisconnectedUI()
            MessageBox.Show(ex.Message)
        End Try
    End Sub

    Public Sub ReceivedData(ByVal ar As IAsyncResult)
        Dim numBytes As Int32

        Try
            SyncLock ClientSocket
                numBytes = ClientSocket.EndReceive(ar)
            End SyncLock
        Catch ex As Exception
            CallDisconnectedUI()
            Return
        End Try

        If numBytes = 0 Then
            '-- Disconnected!
            CallDisconnectedUI()
            Return
        End If

        '-- We have data!
        Dim data As String = _
            System.Text.ASCIIEncoding.ASCII.GetString(recvBuffer, 0, numBytes)
        CallDisplayTextCallback(data)

        '-- Start Receiving Data Again!
        ClientSocket.BeginReceive(recvBuffer, 0, recvBuffer.Length, SocketFlags.None, AddressOf ReceivedData, Nothing)

    End Sub

    Private Sub CallDisplayTextCallback(ByVal Text As String)
        Dim cb As New DisplayTextCallback(AddressOf DisplayText)
        Dim args() As Object = {Text}
        Me.Invoke(cb, args)
    End Sub

    Private Delegate Sub DisplayTextCallback(ByVal Text As String)

    Public Sub DisplayText(ByVal Text As String)
        txtDisplay.AppendText(Text)
        txtDisplay.SelectionStart = txtDisplay.Text.Length
    End Sub

    Private Sub CallDisconnectedUI()
        Dim cb As New SimpleCallback(AddressOf DisconnectedUI)
        Me.Invoke(cb)
    End Sub

    Private Delegate Sub SimpleCallback()

    Public Sub ConnectedUI()
        btnConnect.Text = "Disconnect"
        btnSend.Enabled = True
        Me.AcceptButton = btnSend
    End Sub

    Public Sub DisconnectedUI()
        btnConnect.Text = "Connect"
        btnSend.Enabled = False
        Me.AcceptButton = Nothing
    End Sub

    Private Sub btnSend_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnSend.Click
        '-- Added this code to make it easy for chatting
        Dim SendText As String = txtSend.Text
        If SendText.EndsWith(vbCrLf) = False Then
            SendText &= vbCrLf
        End If

        Dim bytes() As Byte = _
            System.Text.ASCIIEncoding.ASCII.GetBytes(SendText)
        SyncLock ClientSocket
            ClientSocket.Send(bytes, bytes.Length, SocketFlags.None)
        End SyncLock

        '-- Added this code to make it easy for chatting
        txtSend.Clear()
        txtSend.Focus()
    End Sub

End Class